PDP-11 Bootstrap Loader

The PDP-11 Bootstrap Loader is a short program designed to be loaded into the main memory on a PDP-11 via the front panel; it is then run to load an initial program into the machine. I.e. it is a way of bootstrapping a totally empty machine, one with no ROM.

It is designed to be absolutely as short as possible (since it is manually toggled in via the switch register), and therefore has limitations, including how long a program can be loaded using it, and where in memory that program can be placed. The usual program to load with it is the PDP-11 Absolute Loader, which relaxes both of those limitations.

The original bootstrap loader is self-modifying code, since this allows a very short program. The program is not directly self-modifying; rather, the nature of its input is such that it modifies the bootstrap loader as it is read in. (Most bootstrap loader input files eventually restore the bootstrap loader to its original condition, allowing it to be re-used.)

Program

The bootstrap loader contains two locations which are modified by reading the input: the first is a pointer to the buffer in which to place data being read in; the second is a branch back to the beginning of the data input loop.

The program starts with the pointer set to itself, so the blank leader at the start of the data for the bootstrap loader (originally contained on paper tapes) starts with a special leader code which causes this to be left un-changed.

The buffer pointer is then modified to point it slightly before the bootstrap loader in memory, so at the end of the load the newly loaded code then progressively overlays the first several instructions of the bootstrap loader itself, finally patching the buffer pointer to point at the branch instruction, which is then modified to jump to the newly loaded code.

Code

This is the actual bootstrap program:

                        LOAD=xx7400          ; Buffer start address

                        .=LOAD+0344          ; Start address of bootstrap loader (xx7744)

xx7744  016701  START:  MOV DEVICE, R1       ; Get reader CSR address
xx7746  000026
xx7750  012702  LOOP:   MOV #.-LOAD+2, R2    ; Get buffer pointer
xx7752  000352                               ;   (<--- pointer to buffer)
xx7754  005211          INC @R1              ; Enable the paper tape reader
xx7756  105711  WAIT:   TSTB @R1             ; Wait until data available
xx7760  100376          BPL WAIT
xx7762  116162          MOVB 2(R1), LOAD(R2) ; Transfer word to buffer
xx7764  000002
xx7766  xx7400
xx7770  005267          INC LOOP+2           ; Increment pointer to buffer
xx7772  177756
xx7774  000765          BR LOOP              ; Continue reading (<--- modified branch instruction)
xx7776  yyyyyy  DEVICE: yyyyyy               ; Paper tape reader CSR address

When inputting the bootstrap program, the first word is loaded at location xx7744, where xx is replaced with the address of the highest memory bank available according to the following table:

Memory Bank	Total Memory	Bootstrap Location	xx Value
0	4K	017744	01
1	8K	037744	03
2	12K	057744	05
3	16K	077744	07
4	20K	117744	11
5	24K	137744	13
6	28K	157744	15

Note also that, when inputting the word at xx7766, the value (xx7400) should be similarly adjusted.

The value of the word at location xx7776 (yyyyyy) should be replaced with the CSR address of the desired paper tape reader, e.g.:

Console Paper Tape Reader	177560
High-Speed Paper Taper Reader	177550

Bootstrap Loader format

The format of boostrap loader input is as follows:

• Leader (all bytes 0351)
• Load offset (1 byte)
• Program to be loaded (up to 0344 bytes)
• Copy of boostrap loader (first 6 bytes)
• Offset to branch (1 byte)
• Branch modification (1 byte)

Others

Several PDP-11 bootstrap ROMs, e.g. the BM792-YA, BM792-YK and BM873 ROM are prepared to read programs in bootstrap loader format. The code in them is obviously not self-modifying, but reacts to the bootstrap loader input format to produce the same effects.

ODT in the LSI-11 CPUs also has a command to load programs in bootstrap loader format.

Further reading

The Bootstrap Loader is documented in some detail in the "paper tape software programming handbook" (DEC-11-GGPB-D), pp. 6-1 to 6-8.